(defun c:meritko ()
            ;;; definice nové funkce meritko
    (setq id (load_dialog "d:/meritko.dcl"))  ;;; předání jména dialogového boxu
       ;;; CESTU K UMÍSTĚNÍ DIALOGU SE MUSÍ AKTUALIZOVAT PODLE AKTUALNÍHO UMÍSTĚNÍ
       
    (if (not (new_dialog "zoom" id))
      (exit)
    )
            ;;; v případě nesouhlasného jména dialogového
            ;;; panelu (v našem případě zoom - jméno na začátku
            ;;; souboru.dcl) ukončí činnost
    (setq hodn 1)
            ;;; nastavení pomocné proměnné - hodnota zvěšení
    (set_tile "vyber" "zvetseni")
            ;;; nastavení radiotlačítka "zvetseni" ze skupiny
            ;;; "vyber" na aktivní = zvýrazněné
    (action_tile "slider" "(slider_action $value $reason)")
            ;;; získání hodnoty při aktivaci dialogového prvku
            ;;; "slider" a zavolání funkce slider_action 
            ;;; s parametry hodnota a důvod
    (action_tile "editbox" "(ebox_action $value $reason)")
            ;;; získání hodnoty při aktivaci dialogového prvku 
            ;;; "editbox" a zavolání funkce ebox_action
            ;;; s parametry hodnota a důvod
    (action_tile "zvetseni" "(setq radio 0)")
            ;;; při zmáčknutí radio_tlačítka "zvetseni" 
            ;;; se nastavi proměnná radio na 0
    (action_tile "zmenseni" "(setq radio 1)")
            ;;; při zmáčknutí radio_tlačítka "zmenseni" se 
            ;;; nastavi proměnná radio na 1
    (action_tile "accept"
      "(progn 
        (done_dialog)
        (setq ok 1)
      )"
    )
            ;;; při aktivaci tlačítka "accept" = OK se ukončí 
            ;;; dialogový box a nastaví se pomocná proměnná signalizující,
            ;;; že dialogový box byl ukončen tlačítkem OK = potvrzení změn
    (action_tile "cancel"
      "(progn 
        (term_dialog) 
        (setq ok 0)
      )"
    )       ;;; při aktivaci tlačítka "cancel" = ZRUS se ukončí
            ;;; dialogový box a nastaví se pomocná proměnná signalizující,
            ;;; že dialogový box byl zrušen = nepotvrdit změny
    (start_dialog)
            ;;; 		zahájen dialogu
    (unload_dialog id)
            ;;; odstranění dialogu
            ;;; zpracování/nezpracování hodnot získáných z dialogového boxu
    (if (= ok 1)
            ;;; dialog ukončen OK:
      (progn
        (if (= radio 0)
            ;;; rozhodnutí zda zvětšovat/zmenšovat podle hodnoty
            ;;; radio_tlačítek
          (command "zoom" "_S" hodn)
            ;;; zvětšení
          (progn
            (setq hodn (/ 1.0 hodn))
            (command "zoom" "_S" hodn)
            ;;; zmenšení
          )
        )
      )
            ;;; 	CANCEL:
      (setq ok 0)
            ;;; 	vrácení pomocné proměnné na 0
    )
  )

  (defun slider_action (val why)
            ;;; funkce, která v případě aktivace slideru nastaví
            ;;; odpovídající hodnotu v edit_boxu
    (if (or (= why 2) (= why 1))
            ;;; v případě splněných podmínek nastav edit_box,
            ;;; 1 = zmáčknutí entru, 2 = selekce z edit_boxu
      (progn
        (set_tile "editbox" val)
            ;;; 	nastavení hodnoty v edit_boxu
        (setq hodn (atoi val))
            ;;; nastavení pomocné proměnné hodnota zvětšení z proměnné
            ;;; val pomocí konverzestring -> integer
      )
    )
  )

  (defun ebox_action (val why)
      ;;; funkce, která v případě aktivace edit_boxu nastaví odpovídající
      ;;; hodnotu na slideru
    (setq hodn (atoi val))
      ;;; nastavení pomocné proměnné  hodnota zvětšení z proměnné
      ;;; val pomocí konverzestring -> integer
    (if (> hodn 10)
      ;;; v případě, že je hodnota zvětšení/zmenšení větší než 10 (maximální
      ;;; hodnota slideru), pak nastav zvětšení/zmenšení na 10
      (progn
        (setq val "10")
        (set_tile "editbox" val)
      )
    )
    (if (or (= why 2) (= why 1))
            ;;; v případě splněných podmínek nastav slider 
            ;;; 1 = zmáčknutí entru, 2 = selekce z edit_boxu
      (set_tile "slider" val)
    )
  )

;;; nakonec zobrazíme informaci pro uživatele, jak má spustit funkci
(princ "\nNezapomeňte nastavit správnou cestu k dialogu ve funkci zoom!!!")  
(princ "\nFunkce se spustí příkazem (c:meritko) v IDE Visual LISPu")
(princ "\nFunkce se spustí příkazem meritko v AutoCADu")