ok,
actually I got it. I tried to googe it again and I've found the lisp I was looking for.
Here is the lisp just in case somebody would like to use it as well. My thanks goes to Ramesh Gopal on cadalyst forum.

;;; CADALYST 03/08 www.cadalyst.com/code
;;; Tip 2275: TAL.lsp     Align Text (c) 2008 Ramesh Gopal

; Align a group of TEXT in line with a reference TEXT, horizontally or vertically.
; BY G. Ramesh, NPCC, Abu Dhabi, UAE

(defun C:TALIGN(/ ang newpt p1 p2 p3 p4 chk ss sl i ref opt n rlist elist el1 ep)
(setq ss (ssget) sl (sslength ss) i 0
       ref (car(entsel "\nPick the reference TEXT: "))
       chk (reverse(cdr(reverse(assoc 11 (entget ref)))))
       ang (cdr(assoc 50 (entget ref)))
)
(initget "Ver Hor")
(setq opt (getkword "\nAlign TEXT Vertically or Horizontally <Ver>? "))
(if (not opt) (setq opt "Ver"))
(if (equal chk '(11 0.0 0.0)) (setq n 10) (setq n 11))
(setq rlist (assoc n (setq elist (entget ref))))
(repeat sl
(setq el1 (entget(ssname ss i)) ep (assoc n el1))
(if (= opt "Hor")
   (progn
    (setq p1 (cdr rlist) p2 (polar p1 ang 5.0)
      p3 (cdr ep) p4 (polar p3 (+ ang (/ pi 2)) 5.0)
      newpt (inters p1 p2 p3 p4 nil)
    )
    (entmod (subst (list (car ep) (car newpt) (cadr newpt) (last ep)) ep el1))
   )
   (progn
    (setq p1 (cdr rlist) p2 (polar p1 (- ang (/ pi 2)) 5.0)
      p3 (cdr ep) p4 (polar p3 ang 5.0)
      newpt (inters p1 p2 p3 p4 nil)
    )
    (entmod (subst (list (car ep) (car newpt) (cadr newpt) (last ep)) ep el1))
   )
)
(setq i (1+ i))
)(prin1)
)