Shortcut is "DR"

Adjustable via "Aliasedit" if preferred.

Regards 

 

I use two little shortcut commands for not just the DRAWORDER command [which still requires you to specify Back or Front], but for the command with the Back or Front option included in the command operation, without your needing to answer for it [EDIT: just replaced with upgraded version that allows pre-selection]:

 

;;  DraworderBackFront.lsp [command names: DB & DF]
;;  To put selected objects at the Back or Front of the Draworder
;;  Kent Cooper, last edited 20 June 2019 [work with pre-selection]

(defun DBF (which / cmde ss)
  (setq cmde (getvar 'cmdecho))
  (if (ssget "_I")
    (setq ss (ssget "_I")); then
    (progn ; else
      (prompt (strcat "\nTo move to " which " in draw order,"))
      (setq ss (ssget ":L"))
    ); progn
  ); if
  (if ss
    (progn ; then
      (setvar 'cmdecho 0)
      (sssetfirst nil nil); clear if via pre-selection
      (command "_.draworder" ss "" (strcat "_" which) "_.regen")
      (setvar 'cmdecho cmde)
    ); progn
    (prompt "\nNothing selected."); else
  ); if
  (princ)
)

(defun C:DB ()
  (DBF "Back")
)

(defun C:DF ()
  (DBF "Front")
)