CAD tip # 11995:

Kód uložte do souboru RotBy.lsp a načtěte jej přetažením do okna AutoCADu nebo příkazem APLČTI. Pak napište příkaz ROTBY. Vyberte zdrojový objekt s danou rotací a potom postupně vybírejte další objekty, které se mají natočit podle něj.

;Rotate by existing object/angle… (mod by Beekee)
(vl-load-com)

(defun C:RotBy (/ obj rot)
  (if (cond ((setq obj (entsel "\nSelect the source object for rotation < specify manually >: "))
             (and (setq obj (vlax-ename->vla-object (car obj)))
                  (or (not (vl-catch-all-error-p (setq rot (vl-catch-all-apply 'vla-get-rotation (list obj)))))
                      (prompt "\nRotation angle cannot be detected!"))))
            ((setq rot (getangle "\Specify final angle: ")))
      )

    (while (setq obj (entsel "\nSelect next target object to be rotated < exit >: "))
      (and (setq obj (vlax-ename->vla-object (car obj)))
           (or (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-put-rotation (list obj rot))))
               (prompt "\nCannot apply rotation angle!")
               )
           )
      )
    )
  (princ)
)