CAD tip # 11996:

Save the code to the file RotBy.lsp and load it by dragging into the AutoCAD window or with the APPLOAD command. Then type the command ROTBY. Select the source object with the requested rotation angle and then incrementally pick the objects, which should be rotated by it.

;Rotate by existing object/angle… (mod by Beekee)
(vl-load-com)

(defun C:RotBy (/ obj rot)
  (if (cond ((setq obj (entsel "\nSelect the source object for rotation < specify manually >: "))
             (and (setq obj (vlax-ename->vla-object (car obj)))
                  (or (not (vl-catch-all-error-p (setq rot (vl-catch-all-apply 'vla-get-rotation (list obj)))))
                      (prompt "\nRotation angle cannot be detected!"))))
            ((setq rot (getangle "\Specify final angle: ")))
      )

    (while (setq obj (entsel "\nSelect next target object to be rotated < exit >: "))
      (and (setq obj (vlax-ename->vla-object (car obj)))
           (or (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-put-rotation (list obj rot))))
               (prompt "\nCannot apply rotation angle!")
               )
           )
      )
    )
  (princ)
)