Sub Main

	Dim asm As AssemblyDocument = ThisDoc.Document

	lines = New List(Of String)()
	contentCenterPath = ThisApplication.DesignProjectManager.ActiveDesignProject.ContentCenterPath

	Dim fileName As String = SelectFileName()
	If String.IsNullOrWhiteSpace(fileName) Then Return

	Dim occurrences As IEnumerable(Of ComponentOccurrence) = asm.ComponentDefinition.Occurrences.OfType(Of ComponentOccurrence)
	CreateStructure(occurrences, 0)

	System.IO.File.WriteAllLines(fileName, lines.ToArray())
End Sub

Private Function SelectFileName() As String
	Dim saveDialog As Inventor.FileDialog
	ThisApplication.CreateFileDialog(saveDialog)
	With saveDialog
		.Filter = "CSV (Command delimited)(*.csv)|*.csv"
		.DialogTitle = "Specify output filename"
		.OptionsEnabled = False
		.SuppressResolutionWarnings = True
		.CancelError = True
	End With
	Try
		saveDialog.ShowSave()
		Return saveDialog.FileName
	Catch
		Return Nothing
	End Try

End Function

Private lines As List(Of String)
Private contentCenterPath As String

Private Sub CreateStructure(occurrences As IEnumerable(Of ComponentOccurrence), level As Integer)
	For Each occurrence As ComponentOccurrence In occurrences
		If occurrence.BOMStructure = BOMStructureEnum.kReferenceBOMStructure Then Continue For
		If IsContentCenter(occurrence) Then Continue For

		Dim levelPrefix = New String(",", level)
		Dim occName As String = occurrence.Name

		Dim occFileName As String = occurrence.Definition.Document.FullFileName
		lines.Add(String.Format("{0},{1},{2}", levelPrefix, occName, occFileName))

		CreateStructure(occurrence.SubOccurrences.OfType(Of ComponentOccurrence), level + 1)
	Next
End Sub

Private Function IsContentCenter(occurrence As ComponentOccurrence) As Boolean
	Dim doc As Document = occurrence.Definition.Document
	Return doc.FullFileName.StartsWith(contentCenterPath)
End Function