;;======================================================
;; Function: DN_ShowNote
;; Purpose:  Show note selected from ListBox in EditBox
;;======================================================
(defun DN_ShowNote (/ lnum lnote)
(set_tile "error" "")
(setq lnum  (get_tile "lb_notes")
      lnote (nth (atoi lnum) dm_notes)
)
(set_tile "eb_note" lnote)
(princ)
)
;;======================================================
;; Function: DN_PlaceNote
;; Purpose:  If valid note is input, close dialog box
;;======================================================
(defun DN_PlaceNote ()
(set_tile "error" "")
(setq dn_modifier (strcase (get_tile "eb_note")))
(if (= dn_modifier " ")
    (set_tile "error" "Neplatný řetězec poznámky")
    (done_dialog 1)
)   
)
;;======================================================
;; Function: DN_AppendDim
;; Purpose:  Append note to selected dimension entity
;;======================================================
(defun DN_AppendDim (sset mod placement / cnt len ent dval)
(setq cnt 0
      len (sslength sset)
)
(princ "\nUpravuji vybrané kóty...")
(while (< cnt len)
   (setq
           en (ssname sset cnt)
          ent (entget en)
         dval (cdr (assoc 1 ent))
   )
   (if (= dval "")
       (setq dval "<>")
   )
   (if (= placement 1) ;above line
       (setq new_val (strcat dval " " mod))
       (progn
        (if (wcmatch dval "*\\X*")
             (setq new_val (strcat dval " file://\\P - \\P " mod))
             (setq new_val (strcat dval " file://\\X - \\X " mod))
        );if
       );progn    
   );if
   (entmod (subst (cons 1 new_val)(assoc 1 ent) ent))
   (setq cnt (1+ cnt))
);while
(princ "\nDokončeno")
(princ)
)
;;======================================================
;; Main Function - Dimension NOTE
;;======================================================
(defun C:DNOTE (/ cmd$ ss_dims dcl_id dm_notes dn_above)
(princ "\nVyberte text(y) kóty pro úpravu...")
(setq ss_dims (ssget '((0 . "DIMENSION"))))
(if ss_dims
  (progn
   (setq cmd$ (getvar "cmdecho"))
   (setvar "cmdecho" 0)
   (setq dcl_id (load_dialog "dimnotes.dcl"))
   (if (not (new_dialog "dimnote" dcl_id))(exit))
   (setq dm_notes '("VYSKA(PARAPET)" "MAX" "MIN" "OVĚŘIT" "REF" "TEXT"
                     "TYP" "TYPICAL" "VLASTNÍ 1" "VLASTNÍ 2"
                     "ZMĚNA"
                    )
        dn_above   0
   )
   (set_tile "eb_note" "TYP")
   (set_tile "dn_below" "1") ; Set as default
   (start_list "lb_notes")  
   (mapcar 'add_list dm_notes) 
   (end_list)
   (set_tile "lb_notes" "7")
   (action_tile "lb_notes" "(DN_ShowNote)")
   (action_tile "dn_above" "(setq dn_above 1)")
   (action_tile "dn_below" "(setq dn_above 0)")
   (action_tile "accept" "(DN_PlaceNote)")
   (action_tile "cancel" "(done_dialog 0)")
   (if (eq (start_dialog) 1)
       (DN_AppendDim ss_dims dn_modifier dn_above)
   )
   (unload_dialog dcl_id)
   (setvar "cmdecho" cmd$)
  );progn
  (alert "Nebyl vybrán žádný text kóty pro úpravu.")
);if
(princ)
)