Vytisknout stránku | Zavřít okno

přepínač

Vytištěno z: CAD Fórum
Kategorie: Autodesk - stavebnictví, strojírenství, CAD/GIS
Název fóra: AutoCAD
Popis fóra: Otázky kolem aplikací AutoCAD a AutoCAD LT, AutoCAD 360, prohlížečů, DWG a DWF, Design Review, Navisworks, nadstavby, 123D, A360 a cloud Autodesk 360
URL: https://www.cadforum.cz/forum/forum_posts.asp?TID=34530
Datum vytištění: 01.čer.2026 v 00:59


Téma: přepínač
Odeslal: Ondřej Urban
Předmět: přepínač
Datum odeslání: 11.srp.2023 v 12:56
Zdravím,
šlo by tlačítko fungující jako přepínač?
Jedná se mě o rychlé zmrazení / rozmrazení dané hladiny.
Hladina by byla přímo definována v příkazu, nechci vybírat ! např: "text1"
Když by to šlo maskou*, bylo by to úžasné :-)    např: "text*"

díky moc Ondřej


-------------
Ondřej Kurkan Urban
PERI, spol. s r.o.
http://www.peri.cz" rel="nofollow - http://www.peri.cz

WIN 10, 64GB, RTX A4500, 2x27"
ACA 2023, ntb LENOVO P 16 G1


Odpovědi:
Odeslal: Vladimír Michl
Datum odeslání: 11.srp.2023 v 15:31
Šlo, zkuste:

;Layer Freeze/Thaw toggle (Arkance Systems)

(vl-load-com)

(setq *acaddoc* (vla-get-activedocument (vlax-get-acad-object)))

(defun C:LFT ( / LFT_name flg lo)
 (setq LFT_name "MOJEHLADINA") ; layer to process
 (cond
      ( (= (strcase (getvar 'CLayer)) (strcase LFT_name))
        (princ "\nCannot freeze current layer")
      )
      ( (setq lo (tblobjname "LAYER" LFT_name))
        (setq lo (vlax-ename->vla-object lo))
        (vlax-put lo 'Freeze (setq flg (~ (vlax-get lo 'Freeze))))
        (if (= flg 0) (vla-regen *acaddoc* acActiveViewport))
      )
      ( (princ (strcat "\nLayer " LFT_name " does not exist.")))
 )
 (princ)
)

(setq *LFTM_status* nil)

(defun C:LFTM ( / LFT_name)
 (setq LFT_name "MOJEHLADINY*") ; layers to process (mask)
 (command "_-LAYER" (if *LFTM_status* "_FR" "_TH") LFT_name "")
 (setq *LFTM_status* (not *LFTM_status*))
 (princ)
)

(princ "\nLFT and LFTM toggle loaded.")
(princ)


-------------
Vladimír Michl (moderátor)
ARKANCE CZ - https://arkance.world - arkance.world
(podpora viz emea.support.arkance.world)

Odeslal: Ondřej Urban
Datum odeslání: 14.srp.2023 v 12:06
Opět báječné, díky moc...

-------------
Ondřej Kurkan Urban
PERI, spol. s r.o.
http://www.peri.cz" rel="nofollow - http://www.peri.cz

WIN 10, 64GB, RTX A4500, 2x27"
ACA 2023, ntb LENOVO P 16 G1


Vytisknout stránku | Zavřít okno