;;  EllipticalDomeSolid.lsp [command name: EDS]
;;  To construct a Dome shape in Elliptical form, as a 3D Solid.
;;  User specifies Axis lengths, height and precision level.
;;  Constructs with base centered at WCS origin.
;;  To make a hollow dome, construct one to outer dimensions
;;    and another to inner dimensions, and Subtract.
;;  Note that mid-line of each "wedge" surface traces along "true"
;;    dome surface, and "corners" between "wedges" are slightly
;;    outboard of true surface [less so with greater precision].
;;    However, base perimeter is truly Elliptical, with transitional
;;    triangular areas around base.
;;  Kent Cooper, 9 October 2013

(defun C:EDS ; = Elliptical Dome as 3d Solid
  (/ a1 a2 ht prec par ss ell pt ang)
  (command "_.undo" "_begin")
  (setq
    a1 (getdist "\nLength of one elliptical axis: "); = Axis 1
    a2  (getdist "\nLength of other elliptical axis: "); = Axis 2
    ht  (getdist "\nHeight: "); = height
    prec (getint "\nNumber of segments per quadrant [precision]: ")
    par 0.0 ; initial
    ss (ssadd); initially empty
  ); setq
  (setvar 'ucsfollow 0)
  (setvar 'osmode 0)
  (setvar 'blipmode 0)
  (command
    "_.ucs" "_world" "_plan" ""
    "_.zoom" "_c" '(0 0 0) (* (max a1 a2) 1.05)
    "_.ellipse" "_c" '(0 0 0) (polar '(0 0 0) 0 (/ a1 2)) (/ a2 2)
    "_.shademode" "2d"
  ); command
  (setq ell (entlast))
  (repeat (1+ prec)
    (setq
      pt (vlax-curve-getPointAtParam ell par)
      ang (angle '(0 0 0) (vlax-curve-getFirstDeriv ell par))
    ); setq
    (command
      "_.ucs" "_zaxis" '(0 0 0) (polar '(0 0 0) ang 1)
      "_.ellipse"
        "_c" '(0 0 0)
        (trans pt 0 1); even though it will be up off UCS plane
        ht
      "_.extrude" "_last" "" (max a1 a2) ""
      "_.move" "_last" "" (list 0 0 (- (/ (max a1 a2) 2))) ""
      "_.ucs" "_world"
    ); command
    (ssadd (entlast) ss)
    (command "_.mirror" "_last" "" '(0 0 0) '(0 1 0) "_no")
      ; [redundant for first and last, but easier than distinguishing]
    (setq ss (ssadd (entlast) ss))
    (setq par (+ par (/ pi 2 prec)))
  ); repeat
  (command "_.extrude" ell "" ht "")
  (ssadd (entlast) ss)
  (command "_.intersect" ss "")
  (command "_.undo" "_end")
  (princ)
); defun

I load the file with NETLOAD, then at the command prompt, I type ELSOL. The prompts come up asking for the Length, Width, and Height. After entering those values, I get a Fatal Error and get kicked out of AutoCAD.

 

 

SEANT wrote: Here is an updated to work with 2013-2014. Place  Ã¢â‚¬Å›Ellipsoid.dll” on your hard drive.  In AutoCAD, invoke the NETLOAD command and retrieve that file.  If you are using AutoCAD 2014 a warning will be shown if you have not saved it in a Trusted Files Location, but the warning box does give you the option of loading anyway.   For sure, the routine qualifies as rudimentary.  The command can be called via ELLIPSOIDSOLID or ELSOL for short.  The prompt asks for a Length, Width, and Height.  An ellipsoid of the input dimensions is centered at the WCS origin with the axis aligned to the X, Y, and Z. uploads/244286/Ellipsoid.zip

 

Thanks

 

SEANT wrote:   I think the "app" reference pertains to the one I alluded to in my post.  Unfortunately, The compatibility of the routine is only AutoCAD 2011 - 2012.  If needed, I'll try to update to 2013 - 2014, but it wouldn't be available until later this week.  In the mean time, this link has some discussion on the matter as well as hosting my current routine and a lisp variant by Marko Ribar.  See Reply 14.   http://www.theswamp.org/index.php?topic=40429.0