To by sice asi šlo udělat, ale není to zbytečná komplikace? V tom xrefu jsou opravdu čáry individuálně nastaveny na hodně různých měřítek typů čar? Nestačilo by globální LTSCALE/PSLTSCALE a VISRETAIN?

Možných kombinací implicitních a přiřazených měřítek typů čar je hodně. Pokud chcete prostě individuálně přiřazená měřítka vynásobit nějakým koeficientem, můžete použít LISP kód z našeho anglického fóra:

Jeden řádek kódu je tam blbě, teď to fungovalo jen když ltscale bylo defaultně 1. 

Maličko jsem to doplnil, aby se faktor nemusel dopočítávat ručně, ale zadali jsme rovnou nové globální měřítko:



;;change linetype scale by a factor
;;original version: http://www.cadforum.cz/forum_en/forum_posts.asp?tid=11259&title=change-linetype-scale-by-a-factor
;;modified by will garmer to work on selection set instead of single object 2015-07-20
;;fixed Johny 2018-01-03
;;modified by Matejka63 to change the variable "LTSCALE" easily 2018-01-04

(defun c:lsr (/ ss lts_fac count old_val new_val e old_lts new_lts)
 
  ;;=====================================================================================
  ;;main body of c:lsr
 
  ;;get the selection set
  (setq ss (ssget))
 
  ;;get the scale factor by a NEW LTSCALE
    (setq old_lts (getvar "LTSCALE"))
    (setq new_lts (getreal (strcat "Insert a NEW LTSCALE <" (rtos old_lts) ">: ")))
    (if (= new_lts nil)
      (setq new_lts old_lts))
    (setvar "LTSCALE" new_lts)
    (setq lts_fac (/ old_lts new_lts))
 
  ;;do the deed
  (terpri)
  (setq count 0)
  (while    (< count (sslength ss))
    (princ (strcat "\n--> Processing entity no.:" (itoa (+ 1 count)) " of " (itoa (sslength ss)) "... "))
    (setq e (entget (ssname ss count)))
    ;if the object already has a ltscale
    ;then multiply it by the factor
    ;else set the new scale equal to the factor
    (if    (assoc 48 e)
      ;then
      (progn
        (setq old_val (cdr (assoc 48 e))
              new_val (* lts_fac old_val))
        (setq e (subst (cons 48 new_val) (assoc 48 e) e)) ;; johny fixed 2018-01-03
        (entmod e)
        (entupd (ssname ss count))
        );progn then
     
      ;else
      (progn
        (setq new_val (cons 48 lts_fac))
        (setq e (append e (list new_val)))
        (entmod e)
        (entupd (ssname ss count))
        );progn else
      );end if
   
    ;increase the count by one to move on to the next object
    (setq count (+ count 1))
    );while
 
  ;end the program gracefully
  (prompt (strcat "\nEntity linetypescale of **" (itoa (sslength ss)) "** selected objects scaled by a factor of <" (rtos lts_fac) ">. "))
  (princ)
  );defun c:lsr