(defun C:CHGTEXT ( / p l n e os as ns st s nsl osl sl si test chm olderr)
   (setq olderr  *error*             ; Initialize variables
         *error* chgterr
         chm     0)
   (setq p (ssget))                  ; Select objects
   (if p (progn                      ; If any objects selected
      (while (= 0 (setq osl (strlen (setq os (getstring t "\nOld string: ")))))
            (princ "Null input invalid")
      )
      (setq nsl (strlen (setq ns (getstring t "\nNew string: "))))
      (setq l 0 n (sslength p))
      (while (< l n)                 ; For each selected object...
         (if (= "TEXT"               ; Look for TEXT entity type (group 0)
                (cdr (assoc 0 (setq e (entget (ssname p l))))))
            (progn
               (setq test nil si 1)
               (setq s (cdr (setq as (assoc 1 e))))
               (while (= osl (setq sl (strlen
                             (setq st (substr s si osl)))))
                  (if (= st os)
                      (progn
                        (setq s (strcat (substr s 1 (1- si)) ns
                                        (substr s (+ si osl))))
                        (setq test "t") ; Found old string
                        (setq si (+ si nsl))
                      )
                      (setq si (1+ si))
                  )
               )
               (if test (progn        ; Substitute new string for old
                  (setq e (subst (cons 1 s) as e))
                  (entmod e)         ; Modify the TEXT entity
                  (setq chm (1+ chm))
               ))
            )
         )
         (setq l (1+ l))
      )
   ))
   (princ "Changed ")                ; Print total lines changed
   (princ chm)
   (princ " text lines.")
   (terpri)
   (setq *error* olderr)             ; Restore old *error* handler
   (princ)
)

 

 

 

 

 

Měl jsem chvilku na experimentování tak posílám pro inspiraci.

Pro vygenerování scriptu jsem použil Exel, kde v buňkách B-I jsou jednotlivé příkazy a jejich parametry. V buňce A jsou pak tyto příkazy sloučeny (pomocí "&").

 

Sloupec A je pak v Notepadu překopírován (přes schránku) do vykr.scr

 

V novějších verzích Autocdu to nemusí být funkční - nevím zda byla zachována posloupnost parametrů jednotlivých příkazů.

 

Místo "Enter" jsou použity "Mezery" a tak je zápis dost nepřehledný.

 

(script by měl ve všech výkresech vymazat kružnici a text "ddddd" nahradit dle sloupce I ve vykres_11.xls)